[#Part: CMP TallyShopFeatures Left]
	Add : Line  : 	 Enable_MultipleUnitInvoice

[Line :  Enable_MultipleUnitInvoice]
    Field : medium prompt, Enable_MultipleUnitInvoice
    Local : field : medium prompt : set as : "Enable Multiple Unit wise Qty Total in Voucher & Print ?"
    Local : Field : Medium Prompt : width : 35
     
    space top : 0.2 cm
	
[Field :  Enable_MultipleUnitInvoice]
	Use 	: Logical field
    Storage : Enable_MultipleUnitInvoice
	
[#Part: VTYP Main Left]
	add :  Parts   : At End : HVEnable_MultipleUnitInvoice
             
[Part: HVEnable_MultipleUnitInvoice]
	Line	:   HVEnable_MultipleUnitInvoice
	Local	: 	Field	: LongPrompt		: Width		: @@LongWidth + 5
	
[Line: HVEnable_MultipleUnitInvoice]
	Space Top: 2 mm
	
	Field	: Long prompt,HVEnable_MultipleUnitInvoice
	Local	: Field: Long prompt : Set as: "Enable Multiple Unit wise Qty Total in Voucher & Print ?"
			
	Invisible: not @@Enable_MultipleUnitInvoice

[Field: HVEnable_MultipleUnitInvoice]
	Use: logical field
	Storage: Enable_MultipleUnitInvoice
	
[System: formula]
	Enable_MultipleUnitInvoice 			: $Enable_MultipleUnitInvoice:company:##svcurrentcompany
	HVEnable_MultipleUnitInvoice 		: $Enable_MultipleUnitInvoice:voucherType:##SVVoucherType
		
[System: udf]
	Enable_MultipleUnitInvoice 		: Logical	: 11211
	
[#Part: EXPSMP SignOff]
	Add		: Option:vEnable_MultipleUnitInvoice223  : @@Enable_MultipleUnitInvoice AND @@HVEnable_MultipleUnitInvoice 
	
[!Part:vEnable_MultipleUnitInvoice223]
	Add		: Part:At Beginning:InvoiceMultipleUnit_Total
	
[#Part: EXPINV LeftSign]
	Add		: Option:vEnable_MultipleUnitInvoice  : @@Enable_MultipleUnitInvoice AND @@HVEnable_MultipleUnitInvoice 
	
[!Part:vEnable_MultipleUnitInvoice]
	Add		: BottomPart:At Beginning:InvoiceMultipleUnit_Total

[Part:InvoiceMultipleUnit_Total]
	Part	: Empty
	Local	: Part:Empty : Width:6
	
	Part	: InvoiceMultipleUnit_Total2
	
	Space Bottom:.3
	 
[Part:InvoiceMultipleUnit_Total2]
 
	Line	: InvoiceMultipleUnit_Title
	
	Line	: InvoiceMultipleUnit_Total
	Repeat	: InvoiceMultipleUnit_Total : InvoiceMultipleUnit_TotalQtyInventoryEntries
	Border	: Thin Box
	
[Part:InvoiceMultipleUnit_Total2b]
	 
	Part:InvoiceMultipleUnit_Total2b2

[Part:InvoiceMultipleUnit_Total2b1]
	Line	: InvoiceMultipleUnit_Total
	Repeat	: InvoiceMultipleUnit_Total : InvoiceMultipleUnit_TotalQtyInventoryEntries
	Border	: Thin Box
	
[Part:InvoiceMultipleUnit_Total2b2]
	Line	: InvoiceMultipleUnit_Total2
	Repeat	: InvoiceMultipleUnit_Total2 : InvoiceMultipleUnit_TotalQtyInventoryEntries
	Border	: Thin Box
	
[Collection : InvoiceMultipleUnit_TotalQtyInventoryEntries]
	
	Source Collection	: ..
	
	Walk		: Inventory Entries
	
	Fetch		: BilledQty , ActualQty
	
	By			: UnitSymbolBilledQty : $$UnitSymbol:$ActualQty
		 
	Aggr Compute	: ActualQty : Sum : $ActualQty
 
[Line:InvoiceMultipleUnit_Title]
	Fields 			: InvoiceMultipleUnit_TotalName
	Space Bottom	: .2
	Space Top		: .2
	
[Field:InvoiceMultipleUnit_TotalName]
	Use			: name Field
	Set as		: "Unit wise Qty Total"
	Align		: Centre
	Width		: 18
	Style		: Normal Bold
	Color		: White
	Background	: InvoiceMultipleUnit_TotalName
	
[Color:InvoiceMultipleUnit_TotalName]
	RGB			: 30,70,37

[Line:InvoiceMultipleUnit_Total]
	Border		: Thin top
	
	Fields 		: InvoiceMultipleUnit_TotalQty
	Fields 		: InvoiceMultipleUnit_TotalQty2
	
[Line:InvoiceMultipleUnit_Total2]
	Border		: Thin top
	 
	Fields 		: InvoiceMultipleUnit_TotalQty2

[Field:InvoiceMultipleUnit_TotalQty]
	Use			: Qty Field
	Set as		: $ActualQty
	Align		: Right
	Width		: 9
	Style		: Normal Bold
	Background	: White
	
[Field:InvoiceMultipleUnit_TotalQty2]
	Use    	 	: Qty Secondary Field
	Set as		: $ActualQty
	Align		: Right
	Width		: 8
	Style		: Normal Bold
	Background	: White
	
[#Form: GST Comprehensive Invoice Default]
	Add			: Option:vEnable_MultipleUnitInvoice  : @@Enable_MultipleUnitInvoice AND @@HVEnable_MultipleUnitInvoice 
	
[!Form:vEnable_MultipleUnitInvoice]
    Local 		: Part : EXPINV Words         	: Invisible : @@InvGSTAnalysis AND $$ListCount:lvGSTAnalysisDetails > 0 AND ##vItemAnalysisCount <= 5
	Local 		: Part : EXPINV Words         	: Delete:Height

    Local 		: Part : EXPINV EOE	        	: Invisible : @@InvGSTAnalysis AND $$ListCount:lvGSTAnalysisDetails > 0 AND ##vItemAnalysisCount <= 5
	Local 		: Part : EXPINV EOE	        	: Delete:Height
	
    Local 		: Part : EXPINV SignOff       	: Delete:Height
    Local 		: Part : EXPINV MainSignOff   	: Delete:Height
	
[#Form: Export Invoice]
	Add:Option:vEnable_MultipleUnitInvoicec  : @@Enable_MultipleUnitInvoice AND @@HVEnable_MultipleUnitInvoice AND $$InAlterMode
	
[!Form:vEnable_MultipleUnitInvoicec]

	Add		: BottomPart : At End : InvoiceMultipleUnit_Total

	Local	: Part : InvoiceMultipleUnit_Total : Delete	: Part	: InvoiceMultipleUnit_Total2
	Local	: Part : InvoiceMultipleUnit_Total : Delete	: Part	: Empty
	
	Local	: Part : InvoiceMultipleUnit_Total : Add	: Right Part: InvoiceMultipleUnit_Total2,Empty
		
	Local	: Part : InvoiceMultipleUnit_Total : Local	: Line	: InvoiceMultipleUnit_Title : Space Bottom	: .01
	Local	: Part : InvoiceMultipleUnit_Total : Local	: Line	: InvoiceMultipleUnit_Title : Space Top		: .01
	
	Local	: Part : InvoiceMultipleUnit_Total : Local	: Field	: Default : Skip:Yes
	Local	: Part : InvoiceMultipleUnit_Total : Local	: Field	: Default : Set Always:Yes
	